VBScriptで画像を一括リサイズ

VBScriptで画像の一括リサイズを行ないます。
便利なライブラリがあるので、そちらを使用します。
簡単だしPNG対応ってのもGood。
VB標準のLoadPicture関数はPNGに対応してないんですね、、。

Doodle2 VBS用画像描画・変換COMコンポーネント
 http://www.vector.co.jp/soft/winnt/prog/se219120.html

'PicConvertEx.vbs
Option Explicit

Const SCRIPT_NAME = "リサイズたん(*≧ｍ≦)=3"
Dim strExt, rszFolder
Dim yoko, tate, tate_flg, stretch, i
Dim fs, d, objArgs

stretch = False
tate_flg = False
Set fs = WScript.CreateObject("Scripting.FileSystemObject")
Set d = CreateObject("Doodle2.MyCanvas")
Set objArgs = WScript.Arguments 
If objArgs.Count = 0 Then WScript.Quit

yoko = InputBox("横幅のピクセル値を入力して下さい。", SCRIPT_NAME)
If yoko = "" Then WScript.Quit
If IsNumeric(yoko) = False Then
    MsgBox "数値を入力して下さい。", vbExclamation, SCRIPT_NAME
    WScript.Quit
ElseIf yoko = 0 Then
    MsgBox "0px はダメです。", vbExclamation, SCRIPT_NAME
    WScript.Quit
End If
tate = InputBox("縦幅のピクセル値を入力して下さい。", SCRIPT_NAME)
If tate <> "" Then
    tate_flg = True
    If IsNumeric(tate) = False Then
        MsgBox "数値を入力するか、何も入力しないで下さい。", vbExclamation, SCRIPT_NAME
        WScript.Quit
    End If
End If
If tate_flg Then
    If MsgBox("縦横の比率を変えますか？", vbYesNo + vbQuestion, SCRIPT_NAME) = vbYes Then stretch = True
End If

rszFolder = fs.GetParentFolderName(objArgs(0)) & "\Resized"
For i = 0 to objArgs.Count - 1
    strExt = UCase(fs.GetExtensionName(objArgs(i)))
    Select Case strExt
        Case "JPG", "GIF", "PNG", "BMP"
        If fs.FolderExists(rszFolder) = False Then fs.CreateFolder rszFolder
        If tate_flg = False Then
            d.LoadFromFile objArgs(i)
            tate = CLng(d.Height / (d.Width / yoko))
        End If
        d.ConvertFile objArgs(i), rszFolder & "\" & fs.GetFileName(objArgs(i)), strExt, yoko, tate, , , True, stretch
    End Select
Next

Set fs = Nothing
Set d = Nothing

結果的にIfばかりになってごちゃごちゃしてしまった…(笑)
はじめはファイル名の「Ex」が無くて、もっとシンプルなVBScriptでしたが、
最近片幅を決定したらもう片幅を自動で算出する機能を追加して、
なんだか見辛くなってしまいました。でもまぁ使えます。

使い方

リサイズする画像ファイルをドラッグします。勿論、複数ドラッグ(一括リサイズ)も可能。
右クリックの「送る」を使うのも良いです。
オリジナルのデータには上書きせず、画像データのフォルダに「Resized」フォルダが作成され、
その中にリサイズ後のデータが格納されます。
既に同名ファイルが存在する場合、上書きします。
オリジナルのデータは残しての処理なので、上書きで良いかなって(笑)